lkml.org 
[lkml]   [2007]   [Jul]   [11]   [last100]   RSS Feed
Views: [wrap][no wrap]   [headers]  [forward] 
 
Messages in this thread
    Patch in this message
    /
    From
    Subject[x86 setup 30/33] Linker script for the new x86 setup code
    Date
    From: H. Peter Anvin <hpa@zytor.com>

    Linker script to define the layout of the new x86 setup code.
    Includes assert for size overflow and a misaligned setup header.

    Signed-off-by: H. Peter Anvin <hpa@zytor.com>
    ---
    arch/i386/boot/setup.ld | 54 +++++++++++++++++++++++++++++++++++++++++++++++
    1 files changed, 54 insertions(+), 0 deletions(-)
    create mode 100644 arch/i386/boot/setup.ld
    diff --git a/arch/i386/boot/setup.ld b/arch/i386/boot/setup.ld
    new file mode 100644
    index 0000000..df9234b
    --- /dev/null
    +++ b/arch/i386/boot/setup.ld
    @@ -0,0 +1,54 @@
    +/*
    + * setup.ld
    + *
    + * Linker script for the i386 setup code
    + */
    +OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
    +OUTPUT_ARCH(i386)
    +ENTRY(_start)
    +
    +SECTIONS
    +{
    + . = 0;
    + .bstext : { *(.bstext) }
    + .bsdata : { *(.bsdata) }
    +
    + . = 497;
    + .header : { *(.header) }
    + .inittext : { *(.inittext) }
    + .initdata : { *(.initdata) }
    + .text : { *(.text*) }
    +
    + . = ALIGN(16);
    + .rodata : { *(.rodata*) }
    +
    + .videocards : {
    + video_cards = .;
    + *(.videocards)
    + video_cards_end = .;
    + }
    +
    + . = ALIGN(16);
    + .data : { *(.data*) }
    +
    + .signature : {
    + setup_sig = .;
    + LONG(0x5a5aaa55)
    + }
    +
    +
    + . = ALIGN(16);
    + .bss :
    + {
    + __bss_start = .;
    + *(.bss)
    + __bss_end = .;
    + }
    + . = ALIGN(16);
    + _end = .;
    +
    + /DISCARD/ : { *(.note*) }
    +
    + . = ASSERT(_end <= 0x8000, "Setup too big!");
    + . = ASSERT(hdr == 0x1f1, "The setup header has the wrong offset!");
    +}
    --
    1.5.2.2
    -
    To unsubscribe from this list: send the line "unsubscribe linux-kernel" in
    the body of a message to majordomo@vger.kernel.org
    More majordomo info at http://vger.kernel.org/majordomo-info.html
    Please read the FAQ at http://www.tux.org/lkml/

    \
     
     \ /
      Last update: 2007-07-11 21:39    [from the cache]
    ©2003-2014 Jasper Spaans. Advertise on this site